home *** CD-ROM | disk | FTP | other *** search
/ QRZ! Ham Radio 8 / QRZ Ham Radio Callsign Database - Volume 8.iso / pc / files / dsp / 96000tar.z / 96000tar / 96000 / appb / b115c.asm < prev    next >
Assembly Source File  |  1992-04-28  |  9KB  |  192 lines
  1. ; This program was originally published in the Motorola DSP96002 Users Manual
  2. ; and is provided under a DISCLAIMER OF WARRANTY available from Motorola DSP
  3. ; Operation, 6501 William Cannon Drive West, Austin, Texas 78735-8598.  For
  4. ; more information, refer to the DSP96002 Users Manual, Appendix B, DSP
  5. ; Benchmarks.
  6. ;
  7. ; B.1.15.3    Radix 4 Decimation in Frequency FFT  
  8. ;fftr4z macro   points,data,coef,table,temp 
  9. ;fftr4z ident   1,1 
  10. ; 
  11. ; Radix 4 Decimation in Frequency In-Place FFT Routine 
  12. ; 
  13. ;    Complex input and output data 
  14. ;       Real data in X memory 
  15. ;       Imaginary data in Y memory 
  16. ;    Normally ordered input data 
  17. ;    Digit reversed output data 
  18. ;    Coefficient lookup table 
  19. ;       Full cycle sinewave in Y memory 
  20. ;       Coefficient table can be generated by "sinewave" macro. 
  21. ; 
  22. ; 
  23. ; Macro Call - mfftr4z   points,data,coef,table,temp 
  24. ; 
  25. ;       points     number of points (4-16384, power of 4) 
  26. ;       data       starting address of data buffer 
  27. ;       coef       starting address of sinewave table 
  28. ;       table      size of sinewave table 
  29. ;       temp       starting address of temporary storage area 
  30. ; 
  31. ; Cooley-Tukey Radix 4 FFT Algorithm 
  32. ; 
  33. ;            
  34. ; ar,ai                       ar',ai' 
  35. ; br,bi        Radix 4        br',bi' 
  36. ; cr,ci       Butterfly       cr',ci' 
  37. ; dr,di                       dr',di' 
  38. ;             
  39. ; 
  40. ;       t1 = ar + cr 
  41. ;       t2 = ar - cr 
  42. ; 
  43. ;       t3 = dr + br 
  44. ;       t4 = dr - br 
  45. ; 
  46. ;       t5 = ai + ci 
  47. ;       t6 = ai - ci 
  48. ; 
  49. ;       t7 = bi + di 
  50. ;       t8 = bi - di 
  51. ; 
  52. ;       t9 = t2 + t8 
  53. ;       t10 = t2 - t8 
  54. ; 
  55.  
  56. ;       t11 = t6 + t4 
  57. ;       t12 = t6 - t4 
  58. ; 
  59. ;       ar' = t1 + t3 
  60. ;       t13 = t1 - t3 
  61. ; 
  62. ;       ai' = t5 + t7 
  63. ;       t14 = t5 - t7 
  64. ; 
  65. ;       br' = t9*wr1 + t11*wi1 
  66. ;       bi' = t11*wr1 - t9*wi1 
  67. ; 
  68. ;       cr' = t13*wr2 + t14*wi2 
  69. ;       ci' = t14*wr2 - t13*wi2 
  70. ; 
  71. ;       dr' = t10*wr3 + t12*wi3 
  72. ;       di' = t12*wr3 - t10*wi3 
  73. ; 
  74. ; Address pointers are organized as follows: 
  75. ; 
  76. ;       r0 = ar,ai,br,bi pointer        n0 = butterflies per group 
  77. ;       r1 = wr (cos) pointer           n1 = rotation factor 
  78. ;       r2 = temp storage pointer       n2 = groups per pass 
  79. ;       r3 = group index counter        n3 = rotation factor 
  80. ;       r4 = cr,ci,dr,di pointer        n4 = butterflies per group 
  81. ;       r5 = wi (sin) pointer           n5 = rotation factor 
  82. ;       r6 = temp storage pointer       n6 = not used 
  83. ;       r7 = not used                   n7 = not used 
  84. ; 
  85. ; Alters Data ALU Registers 
  86. ;       d0      d4      d8 
  87. ;       d1      d5      d9 
  88. ;       d2      d6 
  89. ;       d3      d7 
  90. ; 
  91. ; Alters Address Registers 
  92. ;       r0      n0      m0 
  93. ;       r1      n1      m1 
  94. ;       r2      n2      m2 
  95. ;       r3      n3      m3 
  96. ;       r4      n4      m4 
  97. ;       r5      n5      m5 
  98. ;       r6              m6 
  99.  
  100. ; 
  101. ; Alters Program Control Registers 
  102. ;       pc      sr 
  103. ; 
  104. ; Uses 6 locations on System Stack 
  105. ; 
  106. ; This program has not been exhaustively tested and may contain errors. 
  107. ; 
  108. ;                                                               ICycles Prog
  109. ;                                                           Word    Cycle
  110.     page                      ; 
  111.     move    #points/4,n0      ;initialize butterflies per group   2    2 
  112.     move    n0,n4             ;            "                      1    1 
  113.     move    #1,n2             ;initialize groups per pass         1    1 
  114.     move    #1,n3             ;initialize w rotation factor       1    1 
  115.     move    #-1,m0            ;initialize linear addressing       1    1 
  116.     move    m0,m1             ;            "                      1    1 
  117.     move    m0,m2             ;            "                      1    1 
  118.     move    m0,m3             ;            "                      1    1 
  119.     move    m0,m4             ;            "                      1    1 
  120.     move    m0,m5             ;            "                      1    1 
  121.     move    m0,m6             ;            "                      1    1 
  122.     move    #temp,r2          ;initialize temp storage pointers   2    2 
  123.     move    (r2)+,r6          ;            "                      1    1 
  124.     move    #0,r3             ;initialize group index counter     1    1 
  125.     move    #coef+table/4,r1  ;initialize wr (cos) pointer        2    2 
  126.     move    #coef,r5          ;initialize wi (sin) pointer        2    2 
  127. ; 
  128. ; Perform all FFT passes with triple nested DO loops 
  129. ; 
  130.     do      #@cvi(@log(points)/@log(4)+0.5),_end_pass   ;          2    3 
  131.     move    #data,r4                                    ;          2    2 
  132.  
  133.     do      n2,_end_grp                                 ;          2    3 
  134.     move    r3,n5          ;update rotation factor                1    1 
  135.     move    n5,n1          ;            "                         1    1 
  136.     move    (r5)+n5        ;point at wi1                          1    1 
  137.     move    (r1)+n1        ;point at wr1                          1    1 
  138.     move    (r4)+n4                                     ;          1    1 
  139.     move    r4,r0          ;point at B data (br,bi)               1    1 
  140.     move    (r4)+n4                                     ;          1    1 
  141.     move    (r4)+n4        ;point at D data (dr,di)               1    1 
  142.  
  143.  
  144.     do      n0,_end_bfy                                 ;          2    3 
  145.     move                             x:(r4),d0.s        ;          1    1 
  146.     move                             x:(r0),d7.s  y:(r4),d2.s  ;   1    1 
  147.     faddsub.s d0,d7                               y:(r0)-n0,d5.s ; 1    1 
  148.     faddsub.s d5,d2                  x:(r0),d1.s                 ; 1    1 
  149.     move                             x:(r4)-n4,d4.s              ; 1    1 
  150.     move                             x:(r4),d4.s  y:(r0),d6.s    ; 1    1 
  151.     faddsub.s d1,d4                  d2.s,x:(r2)+ y:(r4),d3.s    ; 1    1 
  152.     faddsub.s d1,d5                               y:(r1)+n1,d8.s ; 1    1 
  153.     fmpy   d5,d8,d2  faddsub.s d6,d3              y:(r5)+n5,d9.s ; 1    1 
  154.     fmpy   d5,d9,d3  faddsub.s d6,d0 d1.s,x:(r2)- d3.s,y:(r6)    ; 1    1 
  155.     faddsub.s d4,d7                  d0.s,d6.s    d6.s,y:(r2)    ; 1    1 
  156.     fmpy.s d6,d9,d0                               y:(r5)+n5,d9.s ; 1    1 
  157.     fmpy   d6,d8,d0  fadd.s  d0,d2                y:(r1)+n1,d8.s ; 1    1 
  158.     fmpy   d4,d8,d3  fsub.s  d3,d0   x:(r2)+,d1.s y:(r6),d5.s    ; 1    1 
  159.     faddsub.s d5,d1                  x:(r2)-,d6.s                ; 1    1 
  160.     fmpy.s d4,d9,d1                  d7.s,x:(r0)+n0 d1.s,y:      ; 1    1 
  161.     fmpy.s d5,d8,d2                  d2.s,x:(r0)    d0.s,y:      ; 1    1 
  162.     fmpy   d5,d9,d0  fsub.s  d1,d2                y:(r1)-n1,d8.s ; 1    1 
  163.     fmpy   d6,d8,d1  fadd.s  d0,d3                y:(r5)-n5,d9.s ; 1    1 
  164.     fmpy.s d6,d9,d0                  d3.s,x:(r4)  y:(r2),d4.s    ; 1    1 
  165.     fmpy.s d4,d8,d3                               d2.s,y:(r4)+n4 ; 1    1 
  166.     fmpy   d4,d9,d2  fsub.s  d0,d3                y:(r1)-n1,d8.s ; 1    1 
  167.     fadd.s    d2,d1                               y:(r5)-n5,d9.s ; 1    1 
  168.     move                             d1.s,x:(r4)  d3.s,y:        ; 1    1 
  169. _end_bfy 
  170.     move    #coef,r5          ;point at wi0                      ; 2    2 
  171.     move    #coef+table/4,r1  ;point at wr0                      ; 2    2 
  172.     move    #0,r3             ;reset group index counter         ; 1    1 
  173. _end_grp 
  174.     move    n0,d0.l           ;get butterflies per group          1    1 
  175.     lsr     d0.l              ;                                   1    1 
  176.     lsr     d0.l    n2,d1.l   ;divide butterflies/group by 4      1    1 
  177.     lsl     d1.l    d0.l,n0   ;multiply groups/pass by 4          1    1 
  178.     lsl     d1.l    n3,d0.l   ;get w rotation factor              1    1 
  179.     lsl     d0.l    d1.l,n2   ;multiply rotation factor by 4      1    1 
  180.     lsl     d0.l    n0,n4     ;                                   1    1 
  181.     move    d0.l,n3           ;                                   1    1 
  182.     move    n0,d1.l           ;check for 1 butterfly per group    1    1 
  183.     lsr     d1.l              ;                                   1    1 
  184.     jne     skip              ;                                   1    2 
  185.     move    #0,n3             ;reset rotation factor - last pass  1    1 
  186. skip    nop                   ;                                   1    1 
  187. _end_pass                     ;                                 ---  --- 
  188.     endm                      ;                                  78   82 
  189.  
  190. ;The speed for 1024 points using a 75ns instruction cycle is 2.72ms,  assuming internal program and 
  191. ;internal data memory.  
  192.